Após este tutorial, você será capaz de contar o total de caracteres em uma célula ou intervalo, ocorrências de caracteres específicos ou combinação de caracteres em uma célula ou intervalo com ambos diferenciando maiúsculas de minúsculas e alternativas insensíveis. O conhecimento adquirido neste tutorial é uma base realmente boa para uma futura solução criativa de problemas do Excel.

Como contar caracteres no Excel

Se você quiser aprender como contar caracteres no Excel, você precisa usar a função LEN, usando a fórmula = LEN (célula) para contar o total de caracteres em uma célula ou a combinação das funções SUMPRODUCT e LEN para contar o total de caracteres em um intervalo com a fórmula = SUMPRODUCT (LEN (intervalo)). Além disso, a contagem de um caractere específico em uma célula ou intervalo e a combinação específica de caracteres em uma célula ou intervalo será explicada em detalhes.

1. Contagem de caracteres totais em uma célula
2. Contagem de caracteres totais em um intervalo
3. Contagem de caracteres específicos em uma célula
4. Contagem Caractere específico em um intervalo
5. Contagem combinação específica de caracteres em uma célula ou intervalo

Contagem total de caracteres em uma célula

Total de caracteres em um célula pode ser facilmente encontrada usando a função LEN do Excel. Esta função tem apenas um argumento, referência de célula ou texto, onde o número total de caracteres gostaria de ser contado:

=LEN(text)

=LEN(B3)

Esta função conta o total de caracteres em uma célula, incluindo espaços, sinais de pontuação, símbolos, apesar de quantas vezes eles ocorrem em uma string.

Se quisermos contar o total de caracteres em uma célula, excluindo espaços, a combinação das fórmulas LEN e SUBSTITUTE será necessária. Vamos dar uma olhada no exemplo abaixo, a fórmula que exclui espaços se parece com:

=LEN(SUBSTITUTE(B3;" ";""))

A função SUBSTITUTE altera em uma célula definida um caractere / texto com outro caractere / texto. Se quisermos excluir espaços, usando esta função, eles serão eliminados, substituindo todas as ocorrências de espaços por uma string vazia. Após SUBSTITUIR, o texto da função em uma célula seria semelhante a:

= LEN (“Sunisshining”)

Depois disso, é fácil contar o total de caracteres com a função LEN, com o final resultado de 12 caracteres.

Contar o total de caracteres em um intervalo

Para contar o número total de caracteres em um intervalo definido, é necessária a combinação de duas funções, SUMPRODUCT e LEN. Uso da função SUMPRODUCT é uma solução elegante sempre que estamos lidando com várias células ou matrizes. Dê uma olhada no exemplo abaixo e uma combinação das fórmulas:

=SUMPRODUCT(LEN(range))

=SUMPRODUCT(LEN(B3:B6))

A função LEN está relacionada à célula, mas para o uso de faixas de células de funções LEN somadas (= LEN (B3) + LEN (B4) + LEN (B5) + LEN (B6)) não é a melhor solução, pois poderíamos estar lidando com faixas enormes. resultados da função LEN no intervalo definido. Na avaliação da fórmula, o resultado será semelhante a:

Os números da matriz são resultados da função LEN de cada célula no intervalo definido B3: B6, dando resultados finais de 75 caracteres.

A solução alternativa para lidar com intervalos é o uso da combinação de funções SUM e LEN. A sintaxe é quase a mesma, com a única diferença no uso de colchetes, para converter a função SUM na fórmula de matriz (o atalho para criar uma matriz é CTRL + SHIFT + ENTER). Na fórmula abaixo está a sintaxe exata para a combinação de funções SOMA / LEN:

={SUM(LEN(B3:B6))}

Contar Caracteres Específicos em uma Célula

Além do número total de caracteres, existe também a opção no Excel de contar o número de ocorrências de caracteres específicos. Vejamos o exemplo de contagem do número de um único caractere em uma célula específica. Para este propósito, a combinação das funções LEN e SUBSTITUTE é necessária, como fizemos no exemplo semelhante de contagem do número de caracteres na célula sem espaço. A sintaxe da fórmula será semelhante a:

=LEN(cell)-LEN(SUBSTITUTE(cell;character;""))

Em um exemplo específico, se quisermos contar o número de caracteres em um célula B3, a fórmula será semelhante a:

=LEN(B3)-LEN(SUBSTITUTE(B3;"s";""))

Vamos explicar brevemente a lógica da combinação de funções. O número total de caracteres em uma célula B3 é subtraído do número de caracteres na mesma célula, mas sem o caractere específico que queremos contar. Conforme mencionado no tutorial ponto 1, a função SUBSTITUTE é usada para alterar uma string em uma célula definida em uma forma sem caractere específico, substituindo esse caractere por uma string vazia.

=SUBSTITUTE(cell;"character";"")

Pode-se notar no resultado final que a função não está contando caracteres maiúsculos, pois a função LEN diferencia maiúsculas de minúsculas. A solução para contar caracteres sem critérios de distinção entre maiúsculas e minúsculas é o uso da função UPPER / LOWER, onde todos os caracteres serão convertidos para maiúsculas / minúsculas e a função não fará distinção entre maiúsculas e minúsculas.

No exemplo abaixo, a função LOWER está aninhado na função SUBSTITUTE, alterando todas as strings na célula B3 para minúsculas, uma vez que os critérios são definidos como minúsculas, “s”:

=LEN(cell)-LEN(SUBSTITUTE(LOWER(cell);"lowercase character";""))

=LEN(B3)-LEN(SUBSTITUTE(LOWER(B3);"s";""))

Outra solução para tornar a função sem distinção entre maiúsculas e minúsculas é o uso da função SUBSTITUTE aninhada dupla em combinação com a função LEN. No exemplo seguinte, o caractere de contagem estará em uma célula específica, porque às vezes não é prático escrever sempre para contar um caractere na fórmula, especialmente se você estiver lidando com intervalos e fórmulas complexas.

Fórmula com função SUBSTITUTE aninhada dupla:

=LEN(cell)-LEN(SUBSTITUTE(SUBSTITUTE(cell;LOWER(character);"");UPPER(character);""))

=LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))

A fórmula pode parecer complexa, mas tudo ficará claro após a explicação. Vamos avaliar a fórmula passo a passo.

Primeiro, queremos eliminar o caractere de contagem em minúsculas do texto:

=SUBSTITUTE(B3;LOWER(B6);"")

=SUBSTITUTE("Sun is shining ”;LOWER("S”);"")

A função LOWER é colocada para traduzir o caractere de contagem em minúsculas, e então a função + SUBSTITUTE substitui o caractere minúsculo por uma string vazia. Após esta etapa, o resultado da fórmula é parecido com: “Sun i hining”.

Na próxima etapa da fórmula, o objetivo é eliminar o caractere de contagem em maiúsculas do texto / célula definido. Isso é resolvido pela função SUBSTITUTE aninhada :

=SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);"")

Já explicamos dentro do resultado da função SUBSTITUIR “Sun i hining”, e o colocaremos na função abaixo para tornar a situação mais clara. Na primeira função SUBSTITUTE, o caractere minúsculo foi substituído por uma string vazia, e na segunda função SUBSTITUTE, o caractere de contagem maiúscula foi substituído por uma string vazia, resultando no texto sem contar os caracteres “s” e “S”: “un i hining” .

=SUBSTITUTE("Sun i hining”;UPPER("S”);"")

A função LEN então apenas conta o número de caracteres de um texto modificado:

=LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))

=LEN("un i hining”)

Na etapa final, resultado da fórmula avaliada, texto sem “s” e “S” é subtraído pelo número total de caracteres em uma célula definida:

=LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))

=LEN("Sun is shining”) - LEN("un i hining”)

Contar caracteres específicos em um intervalo

Sempre que estamos lidando com intervalos de células e matrizes, a função SUMPRODUCT é necessária em combinação com outras funções. Para contar o específico caractere em um intervalo, para contagem sensível a maiúsculas e minúsculas, a combinação de três funções é usada: SUMPRODUCT, LEN e SUBSTITUTE. Para contagem sem distinção entre maiúsculas e minúsculas, fórmulas adicionais devem ser adicionadas: UPPER / LOWER.

Primeiro, vamos explicar a contagem do número de ocorrências do caractere “S” em um intervalo definido (versão sem distinção entre maiúsculas e minúsculas). Uma fórmula é quase semelhante à fórmula que explica a contagem de caracteres. A diferença vem da função LEN aninhada na função SUMPRODUCT e na área de contagem, em vez da célula é um intervalo definido de células:

=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;"")))

Para contagem de caracteres que não diferencia maiúsculas de minúsculas em um intervalo definido, podemos usar a função explicada detalhada para o caso – contagem de caracteres insensíveis em uma célula específica no ponto 3 do tutorial, com duas alterações: aninhando a função LEN na função SUMPRODUCT e substituindo a célula pelo intervalo de células:

=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);"");UPPER(B9);"")))

Lembre-se, sempre que estiver lidando com intervalos de células, você terá que usar a função SUMPRODUCT. Para caracteres que diferenciam maiúsculas de minúsculas contando em ra Nge combinação de funções é necessária: SUMPRODUCT, LEN e SUBSTITUTE, e para contagem sem distinção entre maiúsculas e minúsculas: funções SUMPRODUCT, LEN, SUBSTITUTE e UPPER / LOWER.

Contagem Combinação específica de caracteres em uma célula ou intervalo

Também existe a possibilidade de contar combinações de caracteres específicas em uma célula ou intervalo definido. Nos pontos anteriores do tutorial, cobrimos a contagem de caracteres únicos em uma célula ou intervalo com alternativas que diferenciam maiúsculas de minúsculas / insensíveis. A fórmula para contar a combinação de caracteres é a mesma, apenas temos que dividi-la com o número de caracteres na combinação de caracteres.

Vamos dar uma olhada no exemplo abaixo, para contar combinações específicas de caracteres em uma célula (versão que não diferencia maiúsculas de minúsculas):

=(LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);"")))/LEN(B6)

A lógica é a mesma para contar um único caractere, apenas tivemos que dividir a fórmula regular com o número de caracteres específicos que estamos contando facilmente usando a fórmula: LEN (“em”). Sem dividir a fórmula com LEN (“em”), o resultado seria multiplicado pelo número de caracteres na combinação de caracteres (em nosso exemplo com 2, já que “em ”Tem dois caracteres)

Para contar combinações específicas de caracteres em uma célula (versão que diferencia maiúsculas de minúsculas), a fórmula será semelhante a:

=(LEN(B3)-LEN(SUBSTITUTE(B3;B6;"")))/LEN(B6)

A combinação de contagem de caracteres em um intervalo tem a mesma lógica de contagem de caractere único e, para maiúsculas e minúsculas, a fórmula da versão confidencial será semelhante a:

=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);"");UPPER(B9);""))))/LEN(B9)

Fórmula regular explicada em tu torials tópico 4, é dividido com o número de caracteres específicos que estamos contando, usando a função LEN.

Se quisermos a versão que não diferencia maiúsculas de minúsculas, a sintaxe da fórmula será semelhante a:

=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;""))))/LEN(B9)

Ainda precisa de ajuda com a formatação do Excel ou tem outras perguntas sobre o Excel? Conecte-se com um especialista em Excel ao vivo aqui para obter ajuda individual. Sua primeira sessão é sempre gratuita.