Hur man räknar tecken i Excel
Efter denna handledning kommer du att kunna räkna totalt antal tecken i en cell eller ett intervall, förekomster av specifik karaktär eller teckenkombination i en cell eller intervall med båda skiftlägeskänsliga och okänsliga alternativ. Kunskap som erhållits i denna handledning är en riktigt bra bas för ytterligare kreativa Excel-problemlösningar.
Hur man räknar tecken i Excel
Om du vill lära dig att räkna tecken i Excel, du måste använda funktion LEN, med formel = LEN (cell) för att räkna totalt tecken i en cell, eller kombination av funktioner SUMPRODUCT och LEN för att räkna totalt tecken i ett intervall med formel = SUMPRODUCT (LEN (intervall)). Dessutom kommer räkning av ett specifikt tecken i en cell eller ett intervall och en specifik kombination av tecken i en cell eller ett område att förklaras i detalj.
- Räkna totalt antal tecken i en cell
- Räkna totalt antal tecken i ett intervall
- Räkna specifikt tecken i en cell
- Antal Specifikt tecken i ett intervall
- Antal Specifik kombination av tecken i en cell eller intervall
Antal totalt tecken i en cell
Totalt antal tecken i en kan enkelt hittas med hjälp av Excel-funktionen LEN. Denna funktion har bara ett argument, cellreferens eller text, där det totala antalet tecken vill räknas:
=LEN(text)
=LEN(B3)
Denna funktion räknar totalt tecken i en cell, inklusive mellanslag, skiljetecken, symboler, trots hur många gånger de förekommer i en sträng.
Om vi vill räkna totalt antal tecken i en cell, exklusive mellanslag, krävs en kombination av formler LEN och SUBSTITUT. Låt oss ta en titt i exemplet nedan, formeln som exkluderar mellanslag ser ut som:
=LEN(SUBSTITUTE(B3;" ";""))
SUBSTITUTE-funktionen ändras i en definierad cell ett tecken / text med ett annat tecken / text. Om vi vill utesluta mellanslag med den här funktionen elimineras de och ersätter alla förekomster av mellanslag med en tom sträng. Efter SUBSTITUTE skulle funktionstext i en cell se ut:
= LEN (”Sunisshining”)
Därefter är det enkelt att räkna totalt tecken med LEN-funktion, med den sista resultat av 12 tecken.
Räkna totalt antal tecken i ett intervall
För att räkna totalt teckennummer i ett definierat intervall krävs kombinationen av två funktioner, SUMPRODUCT och LENN. SUMPRODUCT-funktion är en elegant lösning när vi har att göra med flera celler eller matriser. Ta en titt i exemplet nedan och en kombination av formlerna:
=SUMPRODUCT(LEN(range))
=SUMPRODUCT(LEN(B3:B6))
LEN-funktionen är relaterad till cell, men för cellområden användning av summerade LEN-funktioner (= LEN (B3) + LEN (B4) + LEN (B5) + LEN (B6)) är inte den bästa lösningen eftersom vi skulle kunna hantera stora intervall. I stället för det sammanfattar SUMPRODUCT-funktionen resultat av LEN-funktionen i det definierade intervallet. Vid formelutvärdering kommer resultatet att se ut:
Siffror från matrisen är LEN-funktionsresultat från varje cell i det definierade området B3: B6, vilket ger slutresultat på 75.
Den alternativa lösningen för hantering av intervall är användningen av SUM- och LEN-funktionskombinationer. Syntaxen är nästan densamma, med den enda skillnaden i användning av lockiga parenteser, för att konvertera SUM-funktion i arrayformel (Genväg för att skapa en array är CTRL + SHIFT + ENTER). I formeln nedan är den exakta syntaxen för SUM / LEN-funktionskombination:
={SUM(LEN(B3:B6))}
Räkna specifikt tecken i en cell
Förutom det totala teckennumret finns det också möjlighet att räkna antalet förekomster av specifika tecken i Excel. Låt oss gå igenom exemplet med att räkna antalet enstaka tecken i en specifik cell. För detta ändamål behövs en kombination av LEN- och SUBSTITUTFunktion, som vi gjorde i liknande exempel för att räkna antalet tecken i cellen utan utrymme. Formelsyntax kommer att se ut:
=LEN(cell)-LEN(SUBSTITUTE(cell;character;""))
I ett specifikt exempel, om vi vill räkna antalet tecken s i en definierad cell B3 kommer formeln att se ut:
=LEN(B3)-LEN(SUBSTITUTE(B3;"s";""))
Låt oss kort förklara logiken för funktionskombinationen. Totalt teckennummer i en cell B3 subtraheras med teckennummer i samma cell, men utan specifikt tecken som vi vill räkna. Som nämnts i handledningspunkt 1 används SUBSTITUTE-funktionen för att ändra en sträng i en definierad cell i form utan specifikt tecken, och ersätta det tecknet med en tom sträng.
=SUBSTITUTE(cell;"character";"")
Det kan märkas i slutresultatet att funktionen inte räknar stora tecken eftersom LEN-funktionen är skiftlägeskänslig. Lösningen för att räkna tecken utan skiftlägeskänsliga kriterier är användningen av UPPER / LOWER-funktionen, där alla tecken kommer att översättas till versaler / gemener och funktionen blir skiftlägeskänslig.
I exemplet nedan fungerar funktionen LOWER är kapslad i SUBSTITUTE-funktionen och ändrar all sträng i cell B3 till gemener, eftersom kriterier definieras som gemener, ”s”:
=LEN(cell)-LEN(SUBSTITUTE(LOWER(cell);"lowercase character";""))
=LEN(B3)-LEN(SUBSTITUTE(LOWER(B3);"s";""))
En annan lösning för att göra icke skiftlägeskänslig funktion är användningen av dubbel kapslad SUBSTITUTE-funktion i kombination med LEN-funktionen. I det ytterligare exemplet kommer räknetecknet att finnas i en specifik cell, för ibland är det inte praktiskt att skriva varje gång för att räkna ett tecken i formeln, speciellt om du har att göra med komplexa intervall och formler.
Formel med dubbel kapslad SUBSTITUTE-funktion:
=LEN(cell)-LEN(SUBSTITUTE(SUBSTITUTE(cell;LOWER(character);"");UPPER(character);""))
=LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))
Formeln kan se komplex ut, men allt blir klart efter förklaring. Låt oss utvärdera formeln steg för steg.
Först vill vi eliminera det små bokstäverna från texten:
=SUBSTITUTE(B3;LOWER(B6);"")
=SUBSTITUTE("Sun is shining ”;LOWER("S”);"")
Funktion LOWER sätts för att översätta räknetecken till gemener, och sedan ersätter + SUBSTITUTE-funktionen gemener till en tom sträng. Efter detta stegformelresultat ser ut som: ”Sun i hining”.
I nästa formelsteg är målet att eliminera det stora bokstäverna från den definierade texten / cellen. Detta löses med kapslad SUBSTITUTE-funktion :
=SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);"")
Vi har redan förklarat inuti SUBSTITUTE-funktionsresultatet ”Sun i hining”, och kommer att lägga det i funktionen nedan för att göra situationen tydligare. I den första SUBSTITUTE-funktionen har små bokstäver ersatts med en tom sträng, och i den andra SUBSTITUTE-funktionen ersätts stor bokstavstecken med en tom sträng, vilket resulterar i texten utan att räkna tecknen ”s” och ”S”: ”un i hining” .
=SUBSTITUTE("Sun i hining”;UPPER("S”);"")
LEN-funktionen räknar bara antalet tecken från en modifierad text:
=LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))
=LEN("un i hining”)
I det sista steget utvärderades formelresultatet, text utan ”s” och ”S” subtraheras av det totala antalet tecken i en definierad cell:
=LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);""))
=LEN("Sun is shining”) - LEN("un i hining”)
Räkna specifikt tecken i ett intervall
Närhelst vi har att göra med cellområden och matriser behövs SUMPRODUCT-funktionen i kombination med andra funktioner. För att räkna den specifika tecken i ett intervall, för skiftläge, känslig räkning, används kombinationen av tre funktioner: SUMPRODUCT, LEN och SUBSTITUTE. För skiftlägeskänslig räkning bör ytterligare formler läggas till: UPPER / LOWER.
Först kommer vi att förklara att räkna antalet förekomster av tecken ”S” i ett definierat intervall (skiftlägeskänslig version). En formel är nästan lik formel som förklarar räknetecken. Skillnaden kommer från LEN-funktionen kapslad i SUMPRODUCT-funktionen och i räkningsområdet, istället för cellen definieras cellintervall:
=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;"")))
För skiftlägeskänsliga teckenräkningar i ett definierat intervall kan vi använda den detaljerade förklarade funktionen för fall -känsligt teckenräkning i en specifik cell i handledningspunkt 3, med två ändringar: kapsling av LEN-funktion i SUMPRODUCT-funktion och ersättning av cellen med cellintervall:
=SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);"");UPPER(B9);"")))
Kom ihåg att när du har att göra med cellområden måste du använda SUMPRODUCT-funktionen. För skiftlägeskänsliga tecken räknar i ra nge kombination av funktioner krävs: SUMPRODUCT, LEN och SUBSTITUTE och för skiftlägeskänslig räkning: SUMPRODUCT, LEN, SUBSTITUTE och UPPER / LOWER-funktioner.
Räkna specifik kombination av tecken i en cell eller intervall
Det finns också möjlighet att räkna specifika teckenkombinationer i en definierad cell eller intervall. I tidigare handledningspunkter täckte vi räkning av enstaka tecken i en cell eller ett intervall med skiftlägeskänsliga / okänsliga alternativ. Formeln för att räkna kombinationen av tecken är densamma, bara vi måste dela den med antalet tecken i teckenkombinationen.
Låt oss ta en titt i exemplet nedan för att räkna specifika kombinationer av tecken i en cell (skiftlägeskänslig version):
=(LEN(B3)-LEN(SUBSTITUTE(SUBSTITUTE(B3;LOWER(B6);"");UPPER(B6);"")))/LEN(B6)
Logiken är densamma som för att räkna enstaka tecken, bara vi var tvungna att dela den vanliga formeln med antalet specifika tecken som vi räknar, enkelt med hjälp av formeln: LEN (”in”). Utan att dela formeln med LEN (”in”) skulle resultatet multipliceras med antalet tecken i teckenkombination (i vårt exempel med 2, eftersom ”i ”Har två tecken)
För att räkna specifik kombination av tecken i en cell (skiftlägeskänslig version) kommer formeln att se ut:
=(LEN(B3)-LEN(SUBSTITUTE(B3;B6;"")))/LEN(B6)
Räknekombination av tecken i ett intervall har samma logik som att räkna enstaka tecken, och för fallet kommer känslig versionformel att se ut:
=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(SUBSTITUTE(B3:B6;LOWER(B9);"");UPPER(B9);""))))/LEN(B9)
Regelbunden formel förklarad i tu torials ämne 4, är uppdelat med antalet specifika tecken som vi räknar med funktion LEN.
Om vi vill ha den skiftlägeskänsliga versionen kommer formelsyntaxen att se ut:
=(SUMPRODUCT(LEN(B3:B6))-SUMPRODUCT(LEN(SUBSTITUTE(B3:B6;B9;""))))/LEN(B9)
Behöver du fortfarande hjälp med Excel-formatering eller har du andra frågor om Excel? Anslut med en live Excel-expert här för att få hjälp 1 till 1. Din första session är alltid gratis.